Documentation

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IERC20 {
    function approve(address spender, uint256 amount) external returns (bool);
}

interface IERC3156FlashBorrower {
    function onFlashLoan(
        address initiator,
        address token,
        uint256 amount,
        uint256 fee,
        bytes calldata data
    ) external returns (bytes32);
}

interface IERC3156FlashLender {
    function flashLoan(
        IERC3156FlashBorrower receiver,
        address token,
        uint256 amount,
        bytes calldata data
    ) external returns (bool);
}

contract ExampleBorrower is IERC3156FlashBorrower {
    IERC3156FlashLender public immutable lender;
    bytes32 public constant CALLBACK_SUCCESS =
        keccak256("ERC3156FlashBorrower.onFlashLoan");

    constructor(address lender_) {
        lender = IERC3156FlashLender(lender_);
    }

    function executeFlashLoan(address token, uint256 amount, bytes calldata data) external {
        lender.flashLoan(this, token, amount, data);
    }

    function onFlashLoan(
        address initiator,
        address token,
        uint256 amount,
        uint256 fee,
        bytes calldata /* data */
    ) external override returns (bytes32) {
        require(msg.sender == address(lender), "invalid lender");
        require(initiator == address(this), "invalid initiator");

        // your custom logic here (arbitrage, liquidation, refinancing, etc.)

        IERC20(token).approve(address(lender), amount + fee);
        return CALLBACK_SUCCESS;
    }
}